CRSP compustat merged database in WRDS - Rhea

/* 
 
 This SAS code extracts three company's daily returns on earnings reports dates in 2010.
 Three companies are Microsoft(MSFT), DELL, and IBM.
 
	PERMNO TICKER DATE(first traded date)
	11081 DELL 19880622
	12490 IBM 19620702
	10107 MSFT 19860313
 
 
 Since the primary key of the COMPUSTAT is the gvkey but not PERMNO, we first need to look up which company in CRSP is mapped to
 another company in COMPUSTAT. CRSP/COMPUSTAT MERGED(CCM) database provides us with the mapping table between PERMNO and GVKEY.
 
 Earning report dates are in COMPUSTAT only.
 Therefore this code will find all earning reports date and gvkey.
 Later stocks belong to this gvkeys will be searched in the mapping table so as to get daily returns on the earnings report date.
 Here earning report date is also called RDQ in COMPUSTAT database.
*/
 
libname own  '/home/purdue/YOURNAMEHERE';
libname A_CCM '/wrds/crsp/sasdata/a_ccm';
 
%let begdate = '01JAN2010'd;
%let enddate = '31DEC2010'd;
 
/* We are not interested in earnings reports data not lying between begin date and end date 
  so filter out them.
 */
DATA ERD;
SET compa.fundq;
keep gvkey rdq;
WHERE  rdq<= &enddate AND rdq>=&begdate;
run;
 
DATA LT;
SET a_ccm.ccmxpf_linktable;
keep gvkey lpermno linkdt linkenddt;
run;
 
/* Keep three company's daily returns for 2010 */
proc SQL;
CREATE VIEW DR AS
SELECT d.permno, d.DATE, d.ret 
FROM crspa.dsf d 
WHERE d.permno IN ( 11081, 12490, 10107) AND
   &begdate <= d.date<= &enddate;
 
 /* The linking between PERMNO and GVKEY has expiration date.
   If the mapping is still valid at the time point of DR.date, use the mapping 
   */
 CREATE TABLE retEPdates
 AS SELECT DISTINCT LT.gvkey, LT.lpermno, DR.DATE, DR.ret, LT.linkdt, LT.linkenddt
 FROM DR, LT 
 WHERE DR.permno=LT.lpermno AND DR.DATE >= LT.linkdt AND 
		((LT.linkenddt =.E ) OR (DR.DATE <=LT.linkenddt))
 ORDER BY LT.lpermno, DR.DATE;
 
/* Filter in daily returns on earning reports dates */
 CREATE TABLE MATCH
 AS SELECT DISTINCT t.gvkey, t.lpermno, t.DATE, t.ret, cd.rdq
 FROM retEPdates t, ERD cd
 WHERE cd.gvkey=t.gvkey AND  t.DATE=cd.rdq
 ORDER BY t.lpermno, t.DATE; 
quit;
 
/* temporary dataset will disappear unless you store it.
   One way to save dataset is to store it under your home directory 
   by specifying libname "own"
 */
DATA own.EPdata;
SET MATCH; 
format DATE date9.;
run;